home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Belgian Amiga Club - ADF Collection
/
BS1 part 47.7z
/
BS1 part 47
/
Personal Paint v4.0 (1994)(Cloanto)(M3)(Disk 1 of 2)[WB].7z
/
Personal Paint v4.0 (1994)(Cloanto)(M3)(Disk 1 of 2)[WB].adf
/
InstallPPaint
< prev
next >
Wrap
Text File
|
1993-12-03
|
14KB
|
551 lines
.k ""
.bra {
.ket }
; Install Script Copyright (C) Cloanto Italia 1992, 1993
; Cloanto, Personal Paint, PPaint (R), (TM) Cloanto Italia
; All Rights Reserved - Reproduction Prohibited
; We know some of you prefer other installers. But this one is
; truly multilingual, works with all operating systems and fits
; on the disk. If you have any suggestions, please let us know.
If NOT EXISTS RAM:IPT
MakeDir RAM:IPT
EndIf
If NOT EXISTS RAM:t
MakeDir RAM:t
EndIf
If EXISTS C:Copy
Copy >NIL: C:Copy RAM:IPT
EndIf
CD RAM:IPT
If EXISTS C:If
Copy >NIL: C:If RAM:IPT
EndIf
If EXISTS C:EndIf
Copy >NIL: C:EndIf RAM:IPT
EndIf
If EXISTS C:Execute
Copy >NIL: C:Execute RAM:IPT
EndIf
If EXISTS C:Assign
Copy >NIL: C:Assign RAM:IPT
EndIf
Assign >NIL: PPaint:
Assign >NIL: PPaint: EXISTS
If WARN
Assign >NIL: " PPaint:" EXISTS
If NOT WARN
Assign PPaint: " PPaint:"
EndIf
Assign >NIL: "Copy of PPaint:" EXISTS
If NOT WARN
Assign PPaint: "Copy of PPaint:"
EndIf
Assign >NIL: Copy_of_PPaint: EXISTS
If NOT WARN
Assign PPaint: Copy_of_PPaint:
EndIf
EndIf
Assign >NIL: PPaint: EXISTS
If WARN
Echo "Error: InstallPPaint can only be run from *"PPaint*" disk."
Wait 3 SECS
Skip End2
EndIf
Copy PPaint:c/Print RAM:IPT
If NOT EXISTS PPaint:PPaint_Prefs/PP_Locale/PP_InstallSub
Print "Disk is not configured: default configuration in progress."
Execute PPaint:English
CD RAM:IPT
EndIf
If EXISTS PPaint:PPaint_Prefs/PP_Locale/PP_InstallSub
Execute PPaint:PPaint_Prefs/PP_Locale/PP_InstallSub
EndIf
If NOT EXISTS PLT_trlkll
Print "Error during install."
Wait 3 SECS
Skip End2
EndIf
If EXISTS C:CD
Copy >NIL: C:CD RAM:IPT
EndIf
If EXISTS C:Else
Copy >NIL: C:Else RAM:IPT
EndIf
If EXISTS C:Lab
Copy >NIL: C:Lab RAM:IPT
EndIf
If EXISTS C:Skip
Copy >NIL: C:Skip RAM:IPT
EndIf
If EXISTS C:Delete
Copy >NIL: C:Delete RAM:IPT
Copy >NIL: C:Delete RAM:t
EndIf
If EXISTS C:MakeDir
Copy >NIL: C:MakeDir RAM:IPT
EndIf
If EXISTS C:Wait
Copy >NIL: C:Wait RAM:IPT
EndIf
Copy PPaint:c/CAsk RAM:IPT
Copy PPaint:c/CopyIcon RAM:IPT
Copy PPaint:c/ShowPath RAM:IPT
Copy PPaint:PPaint_Tools/AskAssign RAM:IPT
If EXISTS PPaint:c/Deplode
Copy PPaint:c/Deplode RAM:IPT
EndIf
Version >NIL: graphics.library 36
If WARN
Copy PPaint:PPaint_Icons_1/def_#?.info RAM:IPT CLONE QUIET
Else
Copy PPaint:PPaint_Icons_2/def_#?.info RAM:IPT CLONE QUIET
EndIf
Print PLT_title
; PWrite, C1-Text, PFM trademarks of Cloanto Italia
; DPaintV, DPaintIV, DeluxePaintIII, ADPRO trademarks of respective owners
Assign >NIL: PWrite: EXISTS
If NOT WARN
Assign INTELLASSIGN: PWrite:
EndIf
Assign >NIL: C1-Text: EXISTS
If NOT WARN
Assign INTELLASSIGN: C1-Text:
EndIf
Assign >NIL: PFM: EXISTS
If NOT WARN
Assign INTELLASSIGN: PFM:
EndIf
Assign >NIL: ADPRO: EXISTS
If NOT WARN
Assign INTELLASSIGN: ADPRO:
EndIf
Assign >NIL: DeluxePaintIII: EXISTS
If NOT WARN
Assign INTELLASSIGN: DeluxePaintIII:
EndIf
Assign >NIL: DPaintIV: EXISTS
If NOT WARN
Assign INTELLASSIGN: DPaintIV:
EndIf
Assign >NIL: DPaintV: EXISTS
If NOT WARN
Assign INTELLASSIGN: DPaintV:
EndIf
Assign >NIL: INTELLASSIGN: EXISTS
If NOT WARN
CD INTELLASSIGN:
CD >NIL: /
Assign INTELLASSIGN:
Else
Assign >NIL: Work: EXISTS
If NOT WARN
CD Work:
Else
Assign >NIL: DH1: EXISTS
If NOT WARN
CD DH1:
Else
CD PPaint:
EndIf
EndIf
EndIf
Assign IFONTS:
Execute RAM:IPT/PLC_ipath
If NOT WARN
CD RAM:IPT
Lab Questions
Print >I1 ";"
Print >I2 ";"
Print >PP_WriteOK ";"
Print PLT_askprg
CAsk -y "*e[31m ?"
If WARN
Print >>I1 "Print PLT_infppp"
Print >>I1 "If EXISTS MEMO_DEC"
Print >>I1 " Deplode >NIL: PPaint:PPaint IPPAINT:PPaint"
Print >>I1 "Else"
Print >>I1 " Copy PPaint:PPaint IPPAINT: CLONE"
Print >>I1 "EndIf"
Print >>I1 "CopyIcon >NIL: -r def_PPaint IPPAINT:PPaint"
Print >>I1 "Print *"OK*""
If NOT EXISTS IPPAINT:PPaint_Icons_1
Print >>I1 "MakeDir IPPAINT:PPaint_Icons_1"
EndIf
If NOT EXISTS IPPAINT:PPaint_Icons_2
Print >>I1 "MakeDir IPPAINT:PPaint_Icons_2"
EndIf
If NOT EXISTS IPPAINT:PPaint_Prefs
Print >>I1 "MakeDir IPPAINT:PPaint_Prefs"
EndIf
If NOT EXISTS IPPAINT:Pictures
Print >>I1 "MakeDir IPPAINT:Pictures"
EndIf
If NOT EXISTS IPPAINT:Brushes
Print >>I1 "MakeDir IPPAINT:Brushes"
EndIf
If NOT EXISTS IPPAINT:Colors
Print >>I1 "MakeDir IPPAINT:Colors"
EndIf
If NOT EXISTS IPPAINT:Stencils
Print >>I1 "MakeDir IPPAINT:Stencils"
EndIf
If NOT EXISTS IPPAINT:fonts
Print >>I1 "MakeDir > NIL: IPPAINT:fonts"
EndIf
If NOT EXISTS IPPAINT:PPaint_Tools
Print >>I1 "MakeDir > NIL: IPPAINT:PPaint_Tools"
EndIf
Print > MEMO_DEFDIRS ";"
Print >>I1 "Print PLT_inficn"
Print >>I1 "CopyIcon >NIL: -r def_Drawer IPPAINT:PPaint_Icons_1"
Print >>I1 "CopyIcon >NIL: -r def_Drawer IPPAINT:PPaint_Icons_2"
Print >>I1 "CopyIcon >NIL: -r def_Drawer IPPAINT:PPaint_Tools"
Print >>I1 "CopyIcon >NIL: -r def_Drawer IPPAINT:PPaint_Prefs"
Print >>I1 "CopyIcon >NIL: def_Drawer IPPAINT:Pictures"
Print >>I1 "CopyIcon >NIL: def_Drawer IPPAINT:Colors"
Print >>I1 "CopyIcon >NIL: def_Drawer IPPAINT:Brushes"
Print >>I1 "CopyIcon >NIL: def_Drawer IPPAINT:Stencils"
Print >>I1 "Copy PPaint:PPaint_Icons_1/def_Brush.info IPPAINT:PPaint_Icons_1 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_1/def_Stencil.info IPPAINT:PPaint_Icons_1 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_1/def_Picture.info IPPAINT:PPaint_Icons_1 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_1/def_Palette.info IPPAINT:PPaint_Icons_1 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_1/def_Settings.info IPPAINT:PPaint_Icons_1 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_1/def_Drawer.info IPPAINT:PPaint_Icons_1 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_2/def_Brush.info IPPAINT:PPaint_Icons_2 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_2/def_Stencil.info IPPAINT:PPaint_Icons_2 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_2/def_Picture.info IPPAINT:PPaint_Icons_2 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_2/def_Palette.info IPPAINT:PPaint_Icons_2 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_2/def_Settings.info IPPAINT:PPaint_Icons_2 CLONE"
Print >>I1 "Copy PPaint:PPaint_Icons_2/def_Drawer.info IPPAINT:PPaint_Icons_2 CLONE"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_infuit"
Print >>I1 "Copy PPaint:PPaint_Prefs/UIText.#? IPPAINT:PPaint_Prefs CLONE QUIET"
Print >>I1 "CopyIcon >NIL: -r def_UIText IPPAINT:PPaint_Prefs/UIText.#?"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_infprf"
Print >>I1 "Copy PPaint:PPaint_Prefs/Startup_#? IPPAINT:PPaint_Prefs CLONE QUIET"
Print >>I1 "CopyIcon >NIL: -r def_Settings IPPAINT:PPaint_Prefs/Startup_1.set"
Print >>I1 "CopyIcon >NIL: -r def_Settings IPPAINT:PPaint_Prefs/Startup_2.set"
Print >>I1 "Copy PPaint:PPaint_Prefs/UIColors.#? IPPAINT:PPaint_Prefs CLONE QUIET"
Print >>I1 "CopyIcon >NIL: -r def_Brush IPPAINT:PPaint_Prefs/UIColors.#?"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_infcol"
Print >>I1 "Copy >NIL: PPaint:Colors IPPAINT:Colors ALL CLONE QUIET"
Print >>I1 "CopyIcon >NIL: -r def_Palette IPPAINT:Colors/#?"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_inffn1"
Print >>I1 "Copy PPaint:fonts/Personal.font IPPAINT:fonts CLONE"
Print >>I1 "Copy PPaint:fonts/Personal IPPAINT:fonts/Personal ALL CLONE QUIET"
Assign >NIL: FONTS: EXISTS
If NOT WARN
Print >>I1 "If EXISTS MEMO_FF"
Print >>I1 " Copy PPaint:fonts/Personal.font FONTS: CLONE"
Print >>I1 " Copy PPaint:fonts/Personal FONTS:Personal ALL CLONE QUIET"
Print >>I1 "EndIf"
Print > MEMO_FF ";1"
EndIf
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_infaud"
Print >>I1 "Copy >NIL: PPaint:CloantoAudio DEVS: CLONE"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_infman"
Print >>I1 "Copy PPaint:PPaint.man IPPAINT: CLONE"
Print >>I1 "CopyIcon >NIL: -r def_PPaint.man IPPAINT:PPaint.man"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_infps"
Print >>I1 "Copy PPaint:PPaint_PS IPPAINT: CLONE"
Print >>I1 "CopyIcon >NIL: -r def_PPaint_PS IPPAINT:PPaint_PS"
Print >>I1 "Print *"OK*""
Print >>I1 "Print PLT_inftls"
Print >>I1 "Copy PPaint:PPaint_Tools IPPAINT:PPaint_Tools ALL CLONE QUIET"
Print >>I1 "CopyIcon >NIL: -r def_AskAssign IPPAINT:PPaint_Tools/AskAssign"
Print >>I1 "Print *"OK*""
Version >NIL: graphics.library 36
If NOT WARN
Copy PPaint:PPaint_Prefs/II IPPAINT: ALL CLONE QUIET
EndIf
EndIf
If EXISTS SYS:Classes/DataTypes
If EXISTS DEVS:DataTypes
Version >NIL: graphics.library 39
If NOT WARN
Print PLT_askjpg
CAsk "*e[31m ?"
If WARN
Print > MEMO_JPEG ";"
Print >>I1 "Print PLT_infjpg"
Print >>I1 "Copy >NIL: PPaint:JPEG/Devs/DataTypes/#? DEVS:DataTypes ALL CLONE QUIET"
Print >>I1 "Copy >NIL: PPaint:JPEG/Classes/DataTypes/#? SYS:Classes/DataTypes ALL CLONE QUIET"
Print >>I1 "Print *"OK*""
EndIf
EndIf
EndIf
EndIf
If EXISTS DEVS:Printers
Print PLT_askhpd
CAsk "*e[31m ?"
If WARN
Print >>I1 "Print PLT_infhpd"
Print >>I1 "Copy >NIL: PPaint:HP_DeskJet/Devs/Printers/#? DEVS:Printers ALL CLONE QUIET"
Print >>I1 "Print *"OK*""
EndIf
EndIf
Print PLT_askfn1
CAsk "*e[31m ?"
If WARN
Assign >NIL: FONTS: EXISTS
If NOT WARN
Print >>I1 "If EXISTS MEMO_FF"
Print >>I1 " Print PLT_inffn2"
Print >>I1 " Copy >NIL: PPaint:fonts FONTS: ALL CLONE QUIET"
Print >>I1 " Print *"OK*""
Print >>I1 "EndIf"
Print > MEMO_FF ";2"
EndIf
Else
Print PLT_askfn2
CAsk "*e[31m ?"
If WARN
Print > MEMO_NOBACK ";"
CD IPPAINT:
Execute RAM:IPT/PLC_fpath
If NOT WARN
CD RAM:IPT
Print >>I1 "Print PLT_inffn2"
Print >>I1 "Copy PPaint:fonts IFONTS: ALL CLONE QUIET"
Print >>I1 "Print *"OK*""
EndIf
CD RAM:IPT
EndIf
EndIf
Print PLT_askpc1
CAsk "*e[31m ?"
If WARN
Print > MEMO_PICS ";"
Print >>I2 "Copy >NIL: PPaint:Pictures IPPAINT:Pictures ALL CLONE QUIET"
EndIf
Print PLT_askpc2
CAsk "*e[31m ?"
If WARN
Print > MEMO_PICS ";"
Print >>I2 "Copy >NIL: PPaint_2:Pictures IPPAINT:Pictures ALL CLONE QUIET"
EndIf
If EXISTS MEMO_PICS
Print >>I1 "Print PLT_infpic"
If NOT EXISTS IPPAINT:Pictures
If NOT EXISTS MEMO_DEFDIRS
Print >>I1 "MakeDir IPPAINT:Pictures"
Print >>I1 "CopyIcon >NIL: def_Drawer IPPAINT:Pictures"
EndIf
EndIf
Print >>I2 "CopyIcon >NIL: -r def_Picture IPPAINT:Pictures/#?"
Print >>I2 "Print *"OK*""
EndIf
If EXISTS Deplode
Print PLT_askdec
CAsk "*e[31m ?"
If WARN
Print > MEMO_DEC ";"
EndIf
EndIf
Print ""
Print PLT_askok
CAsk -y "*e[31m ?"
If NOT WARN
If EXISTS MEMO_NOBACK
Skip End1
EndIf
Print PLT_title
Print PLT_askrep
CAsk -y "*e[31m ?"
If WARN
If EXISTS MEMO_DEFDIRS
Delete MEMO_DEFDIRS QUIET
EndIf
If EXISTS MEMO_FF
Delete MEMO_FF QUIET
EndIf
If EXISTS MEMO_JPEG
Delete MEMO_JPEG QUIET
EndIf
If EXISTS MEMO_PICS
Delete MEMO_PICS QUIET
EndIf
If EXISTS MEMO_DEC
Delete MEMO_DEC QUIET
EndIf
Print PLT_title
Skip Questions BACK
Else
Skip End1
EndIf
EndIf
Print PLT_title
Print PLT_infbeg
ShowPath -f IPPAINT:
Print "*e[33m"
If EXISTS MEMO_FF
Copy >NIL: PP_WriteOK FONTS:
If EXISTS FONTS:PP_WriteOK
Delete >NIL: FONTS:PP_WriteOK
If EXISTS SYS:System/FixFonts
Copy >NIL: SYS:System/FixFonts RAM:IPT
Print >>I2 "Print PLT_inffix"
Print >>I2 "FixFonts"
Print >>I2 "Print *"OK*""
EndIf
Else
Delete MEMO_FF QUIET
EndIf
EndIf
CopyIcon >NIL: def_Drawer IPPAINT: 1 1 405 195
Execute I1
Execute I2
Wait 2 SECS
Print PLT_title
Print N "*e[31;1m"
Print PLT_infend
Print "*e[0m*N"
Print PLT_trladd
Print N "*N*e[33m Assign PPaint: "
ShowPath IPPAINT:
Print "*e[31m"
Print PLT_trlfl1
Print PLT_trlfl2
Assign >NIL: S: EXISTS
If NOT WARN
Print ""
Print PLT_askust
CAsk -y "*e[31m ?"
If WARN
Copy >NIL: PP_WriteOK S:
If EXISTS S:PP_WriteOK
If NOT EXISTS S:user-startup
Print >S:user-startup "; BEGIN Personal Paint"
Else
Print >>S:user-startup "*N; BEGIN Personal Paint"
EndIf
Print >>S:user-startup "Assign >NIL: PPAINT: EXISTS"
Print >>S:user-startup N "If NOT WARN*N Failat 21*N EndIf*NAssign >NIL: PPAINT: "
ShowPath >>S:user-startup IPPAINT:
Print >>S:user-startup "; END Personal Paint"
Delete >NIL: S:PP_WriteOK
EndIf
EndIf
If EXISTS MEMO_JPEG
Print PLT_askjst
CAsk -y "*e[31m ?"
If WARN
Copy >NIL: PP_WriteOK S:
If EXISTS S:PP_WriteOK
Assign >NIL: T: EXISTS
If NOT WARN
CD T:
EndIf
Execute RAM:IPT/PLC_jpath
If NOT WARN
CD RAM:IPT
If NOT EXISTS S:user-startup
Print >S:user-startup "; BEGIN PPaint JPEG"
Else
Print >>S:user-startup "*N; BEGIN PPaint JPEG"
EndIf
Print >>S:user-startup "Assign >NIL: JPEGTMP: EXISTS"
Print >>S:user-startup N "If NOT WARN*N Failat 21*N EndIf*NAssign >NIL: JPEGTMP: "
ShowPath >>S:user-startup JPEGTMP:
Print >>S:user-startup "; END PPaint JPEG"
EndIf
CD RAM:IPT
Delete >NIL: S:PP_WriteOK
EndIf
EndIf
EndIf
EndIf
Assign >NIL: IFONTS: EXISTS
If NOT WARN
Print ""
Print PLT_trlfnt
ShowPath IFONTS:
Print "*e[31m"
EndIf
Lab End1
Assign IPPAINT:
Assign IFONTS:
Wait 1 SECS
Print ""
Print PLT_askend
CAsk ""
Else
CD RAM:IPT
Print N "*e[31;1m"
Print PLT_trlkll
Wait 3 SECS
EndIf
Lab End2
CD RAM:t
Delete > NIL: RAM:IPT ALL QUIET
Delete > NIL: Delete